ASP中在VBScript中使用類的介紹說明

本文主要跟大家一起分享的是ASP中在VBScript中使用類的介紹說明，希望能夠給大家?guī)�來幫助或啟發(fā)。

前言
　　首先，在我進入實質(zhì)性主題并解釋如何建立類之前，我希望保證你知道“對象”。雖然你可以在程序中使用對象而不用知道其正確的規(guī)則，但我并不建議如此！對于對象的初學者，接下來的部分將讓你了解其概念及內(nèi)容。已經(jīng)了解面向?qū)ο缶幊蹋∣OP）的讀者可以跳過這章節(jié)。

　　導論
　　“對象是什么？”——對象通常代表某種實體，主要是一個變量和函數(shù)的集合。
　　“實體是什么？”——字面上說，實體是一個“事物”，我的意思是一個概念或者任何一個物體。例如，一輛汽車是一個實體，因為它是一個物體。你公司銷售部門銷售產(chǎn)品也是一個實體，當然，你也可以將其拆開來看，銷售人員、客戶、產(chǎn)品等都是實體。

　　讓我們更深入的來看“銷售”這個實體（對象）。為了使你更準確地有一個銷售的“映像”，你需要知道客戶買了什么，是哪個客戶，誰是銷售人員等等……這看來是一個簡單的事件，但假設所有信息是存儲在單獨的數(shù)據(jù)庫表中的，那么當你需要獲得某個銷售過程所有相關信息時，你必須在你的數(shù)據(jù)庫中做多次獨立查詢，再將所有的數(shù)據(jù)集攏。有沒有更簡便的辦法而一次獲得銷售的所有信息呢？“對象”。

　　在對象中，你可以植入代碼以從其他表中獲得數(shù)據(jù)，你也可以保存對象屬性的所有信息，這樣，你可以輕松地使用代碼管理你的銷售數(shù)據(jù)。例如：
'Open the database connection
Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open "MyDSN"

'Create the recordset object
Set objRS = Server.CreateObject("ADODB.Recordset")

'Define the SQL query
strComplexSQLQuery = "SELECT C.Name, S.Name FROM Customers C, " & _
"Salespeople S, Sales Sl WHERE Sl.CustomerID=C.ID AND " & _
"Sl.SalespersonID=S.ID AND Sl.ID=" & strIDOfThisSale & ";"

'Open the recordset
objRS.Open strComplexSQLQuery, objConn, adOpenForwardOnly, _
adLockReadOnly, adCmdText

'Take the customer and sales person names from the recordset
strCustomerName = objRS(0)
strSalesPersonName = objRS(1)

'Tidy up the objects
objRS.Close
objConn.Close
Set objRS = Nothing
Set objConn = Nothing

'Output the data
Response.Write "This sale was made by " & strSalesPersonName & _
" to " & strCustomerName

　　可以使用“對象”來替代：
'Create the "Sale" object
Set objSale = New Sale

'Lookup the correct sale
objSale.ID = strIDOfThisSale

'Output the data
Response.Write "This sale was made by " & objSale.SalesPersonName & _
" to " & objSale.CustomerName

'Tidy up the objects
objSale.Close
Set objSale = Nothing

　　如果你使用“Sale”對象做比打印更多的事，可以讓你省去很多的打字時間。

　　計算中，對象包括“屬性”和“方法”。屬性主要是儲存在對象中的一個變量，其用法與變量相同。唯一的區(qū)別在于參數(shù)賦值為：strMyVar = "This is a string variant", 而對象屬性為 objObject.Property="This is a string variant"。這點非常簡單而有用處。方法可以理解為植入對象中的函數(shù)與過程，可以使用strMyVar = objObject.MethodName(strMyVar)來代替strMyVar =FunctionName(strMyVar)。寫法不同，但功能相同。屬性的一個例子是對象Response中的ExpireAbsolute，Response.ExpiresAbsolute = CDate("1 September 1999")。方法的一個例子是對象Response中的Write方法，Response.Write "Hello world!"。

　　VBScript的一個新特性就是其可以創(chuàng)建新的對象而不需要求諸于花銷時間都極大的編譯器。我將向讀者展示如何創(chuàng)建對象的類，并希望提供一個良好的開端。

　　創(chuàng)建對象
　　在VBScript中創(chuàng)建對象類型（類）時，你首先要知道，這真的很容易！我在一個下午自學，只是閱讀了Microsof VB Script 的參考書，但必須承認，這書不是最容易閱讀的文檔。

　　初學者需要安裝VBScript 5.0引擎，可以在microsoft's Scripting Site下載。

　　我們來看代碼。類的定義與函數(shù)和子過程非常類似。起始行為Class ，結尾是End Class，所有的對象定義寫在中間部門�，F(xiàn)在我們可以用所學的來建立第一個類，不實現(xiàn)任何功能的類。
Class 4GuysTestObject

End Class

　　這看上去不是那么回事，但當你寫入下面的代碼后，你將創(chuàng)建一個對象的實例：
Dim objTestObject
Set objTestObject = New 4GuysTestObject
Set objTestObject = Nothing

　　顯然，我們現(xiàn)在還不能用對象做任何事，現(xiàn)在我將解釋如何在對象中定義屬性和方法。

　　使用對象可以做的最基礎的，是建立一組數(shù)據(jù)。例如，假如要將時間、日期及視頻程序標題建立在一起，你可以創(chuàng)建一個包含屬性“StartTime”， “ProgramDate”和“ProgramTitle”的對象。代碼如下：
Class TVProgram
Public StartTime
Public ProgramDate
Public ProgramTitle
End Class

Dim objTVShow
Set objTVShow = New TVProgram
objTVShow.StartTime = CDate("17:30")
objTVShow.ProgramDate = DateSerial(1999,9,17)
objTVShow.ProgramTitle = "The Jerry Springer Show"

Response.Write objTVShow.ProgramTitle & " is on at " & _
objTVShow.StartTime & " on " & objTVShow.ProgramDate

　　代碼工作的方式是，我們定義StartTime，ProgramDate和ProgramTitle為類TVProgram的屬性。這樣，這些屬性就像其他變量一樣來處理，沒有設置值則不會執(zhí)行代碼。屬性名字前的Public字段有其真實含義，而且非常重要。如果你不特指一個方法或?qū)傩詾閜ublic或private，系統(tǒng)默認值為public，但最好養(yǎng)成定義任何值的良好書寫習慣（也方便你之后自己的閱讀）。

　　上面程序的結果大致如下（決定于你的本地服務器配置）：The Jerry Springer Show is on at 5:30pm on 17/09/99.

　　我在英國，所以日期現(xiàn)實如上。不論你跑什么工程，它的效果都不錯，但只有你開始使用其他對象的功能，為你可能需要的所有信息和功能，創(chuàng)建一個完美的接口，以支持你所建對象包圍的實體，你才會體會到對象的真正實力。

　　現(xiàn)在，如果你不喜歡上面例子顯示日期的方法，而希望以同一種格式現(xiàn)實日期，也沒有不要在引用每個ProgramDate屬性時加FormatDateTime(),你只需要將此類代碼植入屬性本身。

　　這樣需要用另一種方法定義屬性。同樣，我們將使用ProgramDate為外部可見屬性，但因為ProgramDate屬性將成為一個函數(shù)而不是靜態(tài)值，我們將實際日期保存在另一個屬性中internal_ProgramDate。

Class TVProgram
Public StartTime

Public internal_ProgramDate

Public Property Get ProgramDate
ProgramDate = Day(internal_ProgramDate) & _
" " & MonthName(Month(internal_ProgramDate)) & _
" " & Year(internal_ProgramDate)
End Property

Public ProgramTitle
End Class

Dim objTVShow
Set objTVShow = New TVProgram

objTVShow.StartTime = CDate("17:30")
objTVShow.internal_ProgramDate = DateSerial(1999,9,17)
objTVShow.ProgramTitle = "The Jerry Springer Show"

Response.Write objTVShow.ProgramTitle & " is on at " & _
objTVShow.StartTime & " on " & objTVShow.ProgramDate & "."

　　程序的結果如下：
The Jerry Springer Show is on at 5:30pm on 17 September 1999

　　我們來分析一下（2）中的程序：
Class TVProgram
Public StartTime
Public internal_ProgramDate
Public Property Get ProgramDate
ProgramDate = Day(internal_ProgramDate) & _
" " & MonthName(Month(internal_ProgramDate)) & _
" " & Year(internal_ProgramDate)
End Property

Public ProgramTitle
End Class

Dim objTVShow
Set objTVShow = New TVProgram
objTVShow.StartTime = CDate("17:30")
objTVShow.internal_ProgramDate = DateSerial(1999,9,17)
objTVShow.ProgramTitle = "The Jerry Springer Show"
Response.Write objTVShow.ProgramTitle & " is on at " & _
objTVShow.StartTime & " on " & objTVShow.ProgramDate & "."

　　當調(diào)用對象的屬性ProgramDate時，實際上執(zhí)行了函數(shù)ProgramDate，即如上定義的函數(shù)，而很快你也將習慣這種在聲明部分使用Public或Private關鍵字的方式。關鍵字“Property”，告知了編譯器如同調(diào)用屬性一樣在外部調(diào)用函數(shù)。接著的“Get”，表明該函數(shù)是輸出還是獲得一個值。

　　Get的意思是“允許外部代碼去‘獲取’一個值”，與其類似的關鍵字還有“Let”和“Set”，但這兩個比較復雜，因而我們以后再討論。

　　接下去的代碼看來有點難度的，給objectname.internal_ProgramDate賦值并通過objectname.ProgramDate來調(diào)用它。如果可以使用相同關鍵字同時為其賦值并獲得它的值不是更好嗎？當然，那也可以。

　　如果定義Get和Let屬性的名稱相同，可以將它們當作對象相同的屬性，但這只限于它們定義了相同數(shù)量的成員。（以下代碼看來不太相同，僅作為實例參考）
Class TVProgram
Public StartTime
Public internal_ProgramDate
Public Property Get ProgramDate
ProgramDate = Day(internal_ProgramDate) & " " _
& MonthName(Month(internal_ProgramDate)) & _
" " & Year(internal_ProgramDate)
End Property

Public Property Let ProgramDate(ByVal varDateIn)
internal_ProgramDate = CDate(varDateIn)
End Property

Public ProgramTitle
End Class

Dim objTVShow
Set objTVShow = New TVProgram
objTVShow.StartTime = CDate("17:30")
objTVShow.ProgramDate = "17 Sept 99"
objTVShow.ProgramTitle = "The Jerry Springer Show"
Response.Write objTVShow.ProgramTitle & " is on at " & _
objTVShow.StartTime & " on " & objTVShow.ProgramDate & "."

　　以上代碼中Let的聲明部分看來似乎是一個多余的元素，當我第一次看到時研究了很長時間。每次我使用“0”作為變量用在每個屬性上，我總是得到這個錯誤信息，“元素數(shù)量必須相等”。“它們確實相等！”抓狂之后，我回過頭去看程序才覺得自己的愚蠢�。海�

　　原因是，當你試圖為ProgramDate賦值時，你會使用這樣一行程序：objTVShow.ProgramDate = dtmMyDate

　　為了方便，等號右邊的值（這里指dtmMyDate）作為了一個程元賦給了函數(shù)。因此編譯器可能會認為在Get ProgramDate行有0程元，而Let ProgramDate卻多一個！分配的值總是被略過而作為屬性的最后一個程元，所以即使你使用其他程元，所賦的值總是作為最后一個程元。

　　現(xiàn)在看程序。無論通過ProgramDate設置日期為文本形式，還是用internal_ProgramDate譯成日期變量，程序都沒有問題。但能不能只使用一個入口呢？

　　如果internal_ProgramDate只能在內(nèi)部有效，而使用Let ProgramDate檢查傳輸?shù)臄?shù)據(jù)類型，我們就可以作出選擇。例如：
Class TVProgram
Public StartTime
Private internal_ProgramDate
Public Property Get ProgramDate
ProgramDate = Day(internal_ProgramDate) & " " & _
MonthName(Month(internal_ProgramDate)) & _
" " & Year(internal_ProgramDate)
End Property

Public Property Let ProgramDate(ByVal varDateIn)
If IsDate(varDateIn) Then
internal_ProgramDate = varDateIn
Else
'Place some error handling code in here.
End If
End Property

Public ProgramTitle
End Class

并同樣聲明StartTime屬性：
Class TVProgram
Private internal_StartTime
Public Property Get StartTime
StartTime = Hour(internal_StartTime) & ":" _
& Minute(internal_StartTime)
End Property

Public Property Let StartTime(ByVal varTimeIn)
If IsDate(varTimeIn) Then
internal_StartTime = varTimeIn
End If
End Property

Private internal_ProgramDate
Public Property Get ProgramDate
ProgramDate = Day(internal_ProgramDate) & " " _
& MonthName(Month(internal_ProgramDate)) & _
" " & Year(internal_ProgramDate)
End Property

Public Property Let ProgramDate(ByVal varDateIn)
If IsDate(varDateIn) Then
internal_ProgramDate = varDateIn
End If
End Property

Public ProgramTitle
End Class
...
　　現(xiàn)在的代碼離我們想要的還是有些不太實用，我們將在其他頁使用類TVProgram，因此最好將其獨立定義，以便所有也面都可以調(diào)用。我們將在第四部分討論這點。

　　現(xiàn)在的代碼離我們想要的還是有些不太實用，我們將在其他頁使用類TVProgram，因此最好將其獨立定義，以便所有也面都可以調(diào)用。創(chuàng)建一個ASP頁面，并命名為TVProgramClass.asp，我們在其中定義類TVProgram。

--TVProgramClass.asp--
<%
Class TVProgram
Private internal_StartTime
Public Property Get StartTime
StartTime = Hour(internal_StartTime) & ":" & Minute(internal_StartTime)
End Property

Public Property Let StartTime(ByVal varTimeIn)
If IsDate(varTimeIn) Then
internal_StartTime = varTimeIn
End If
End Property

Private internal_ProgramDate
Public Property Get ProgramDate
ProgramDate = Day(internal_ProgramDate) & " " & MonthName(Month(internal_ProgramDate)) & " " & Year(internal_ProgramDate)
End Property

Public Property Let ProgramDate(ByVal varDateIn)
If IsDate(varDateIn) Then
internal_ProgramDate = varDateIn
End If
End Property

Public ProgramTitle
End Class
%>

　　這樣就可以在任何ASP中調(diào)用我們定義的類了，語法如下：
<!-- #include virtual="TVProgramClass.asp" -->
<%
Dim objTVShow
Set objTVShow = New TVProgram
objTVShow.StartTime = CDate("17:30")
objTVShow.ProgramDate = DateSerial(1999,9,17)
objTVShow.ProgramTitle = "The Jerry Springer Show"
response.write objTVShow.ProgramTitle & " is on at " & objTVShow.StartTime & " on " & objTVShow.ProgramDate & "."
%>

　　這里有一個建議。如果你重命名你的包含文件.asp，并保證所有重要代碼都在<% ... %>中，那么就算有人猜到了你包含文件的文件名，也沒辦法看見里面的內(nèi)容！